//Steiner's Roman Surface
//by Adam Coffman

  camera {
    location <8.77, 9.288, -10>
    look_at 0
  }                 
    #include "colors.inc"          
    #include "stones.inc"          
    #declare S1 = 
texture {
    pigment {
        granite  
        color_map {
            [0.72 rgb 0.00 ] 
            [0.72 rgb 0.20 ] 
            [0.75 rgb 0.40 ] 
            [0.78 rgb 0.60 ]
            [0.81 rgb 0.80 ] 
            [0.85 rgb 0.95 ] 
            [0.91 rgb 1.00 ] 
            [0.91 rgb 0.00 ] 
        }
    scale .015
    }
    finish { ambient 1 }
}
plane { <15,16,-20>,  -15  texture{S1   scale 20 }      }
#declare C1 = pigment {
      bozo
      turbulence 1
      color_map {
        [0.0 color White filter 1]
        [0.5 color White]
        [1.0 color White filter 1]
      }
    }
  #declare C2 = pigment {
    agate
    turbulence 1
    color_map {
      [0.0 color White filter 1]
      [0.5 color White]
      [1.0 color White filter 1]
      }
    }
  #declare C3 = pigment {
    marble
    turbulence 1
    color_map {
      [0.0 color White filter 1]
      [0.5 color White]
      [1.0 color White filter 1]
    }
  }
  #declare C4 = pigment {
    granite
    turbulence 1
    color_map {
      [0.0 color White filter 1]
      [0.5 color White]
      [1.0 color White filter 1]
    }
  }
  #declare T1 = texture {
      pigment {
        agate
        turbulence 1
        lambda 1.5
        omega .8
        octaves 8
        color_map {
          [0.00 color rgb <.5, .25, .15>]
          [0.33 color rgb <.1, .5, .4>]
          [0.86 color rgb <.6, .3, .1>]
          [1.00 color rgb <.5, .25, .15>]
        }
      }
    }
  #declare T2 = texture {
      pigment {
        bozo turbulence .5 
        lambda 2
        color_map {
          [0.00, 0.33 color rgb <0, 0, 1>
                      color rgb <0, 0, 1>]
          [0.33, 0.66 color rgbf <1, 1, 1, 1>
                      color rgbf <1, 1, 1, 1>]
          [0.66, 1.00 color rgb <0, 0, 1>
                      color rgb <0, 0, 1>]
        }
      }
    }
  #declare CloudArea = texture {
    pigment {
      gradient y
      pigment_map {
        [0.00 C1]
        [0.25 C2]
        [0.50 C3]
        [0.75 C4]
        [1.00 C1]
      }
    }
  }
poly { 4<
  0, 0, 0, 0, 1, 0, 0, 1, 0, 0, 0, 0, 0, 0, 1, 
  0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 
  0, 0, 0, 0, 0>                 sturm 
      texture{T_Grnt9} finish{ambient 0.5}
    bounded_by { box { <-0.5,-0.5,-0.5> ,<0.5,0.5,0.5> } }
    clipped_by { bounded_by }                     
   scale<5.5,5.5,5.5> rotate<0,0,40> rotate<35,0,0> translate<0,0,15>   
    }     
poly { 4<
  0, 0, 0, 0, 1, 0, 0, 1, 0, 0, 0, 0, 0, 0, 1, 
  0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 
  0, 0, 0, 0, 0>                 sturm 
    texture { T1 scale 2} finish{ambient 0.3}
    texture { T2 rotate<95,0,0>rotate<0,19,0>}  finish{ambient 0.3} 
    bounded_by { box { <-0.5,-0.5,-0.5> ,<0.5,0.5,0.5> } }
    clipped_by { bounded_by }                     
    scale<12,12,12>    rotate<0,0,1>
  }
poly { 4<
 0, 0, 0, 0, 1, 0, 0, 1, 0, 0, 0, 0, 0, 0, 1, 
 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 
 0, 0, 0, 0, 0>                 sturm 
 texture { CloudArea scale .6 rotate x*90}
  bounded_by { box { <-0.5,-0.5,-0.5> ,<0.5,0.5,0.5> } }
  clipped_by { bounded_by }                     
  scale<12.75,12.75,12.75>    rotate<0,0,1>
  }              
                                            
light_source { <1000, 1000, -1000> White }